e11sync/pkgs/e11sync-backend.nix

{
  lib,
  stdenv,
  runCommand,
  makeWrapper,
  python3,
  python3Packages,
  libmaxminddb,
  dart-sass,
  uwsgi,
  backendPort ? 8002,
  database-path ? null,
  geoip-mmdb,
}:
stdenv.mkDerivation {
  name = "e11sync";
  propagatedBuildInputs = let
    pythonEnv = python3.withPackages (ps:
      with ps; [
        django_5
        django-compressor.override
        {django = django_5;}
        #{django-appconf = django-appconf.override {django = django_5;};}
        geoip2
      ]);
  in [
    pythonEnv
    libmaxminddb
  ];
  nativeBuildInputs = [makeWrapper];
  src = ../app;
  patchPhase = ''patchShebangs --build manage.py'';
  buildPhase = ''mkdir -p $out'';
  installPhase = ''
    cp -r . $out/app
    makeWrapper $out/app/manage.py $out/bin/e11sync \
      --set GEOIP_PATH "${geoip-mmdb}"

    makeWrapper ${uwsgi}/bin/uwsgi $out/bin/e11sync-backend \
      --chdir $out/app \
      --set-default E11SYNC_HTTP_PORT ${toString backendPort} \
      --add-flags "--plugin ${uwsgi}/lib/uwsgi/python3_plugin.so" \
      --add-flags "--http-socket 127.0.0.1:${toString backendPort}" \
      --add-flags "--wsgi-file e11sync/wsgi.py" \
      --add-flags --master \
      ${lib.optionalString (database-path != null) ''
      --set E11SYNC_DATABASE_PATH "${database-path}" \
    ''} \
      --set E11SYNC_DEBUG "" \
      --set E11SYNC_COMPRESS_OFFLINE 1 \
      --set GEOIP_PATH "${geoip-mmdb}" \
  '';
  passthru.tests.unit =
    runCommand "e11sync-test" {
      src = ../app;
      buildInputs = [
        python3Packages.django_5
        python3Packages.django-compressor
        python3Packages.geoip2
        dart-sass
      ];
    } ''
      unpackPhase
      patchShebangs --build app/manage.py
      export GEOIP_PATH="${geoip-mmdb}"
      app/manage.py test app
      mkdir -p $out
    '';
}