{
  nixConfig = {
    trusted-substituters = "https://cache.nixos.org/";
    trusted-public-keys = "cache.nixos.org-1:6NCHdD59X431o0gWypbMrAURkbJ16ZPMQFGspcDShjY=";
    extra-experimental-features = "nix-command flakes";
  };
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.11";
    flake-utils.url = "github:numtide/flake-utils";
    geoip2-asn = {
      url = "https://dl.jakstys.lt/_/2024.01.10/GeoLite2-ASN.mmdb";
      flake = false;
    };
    geoip2-city = {
      url = "https://dl.jakstys.lt/_/2024.01.10/GeoLite2-City.mmdb";
      flake = false;
    };
    geoip2-country = {
      url = "https://dl.jakstys.lt/_/2024.01.10/GeoLite2-Country.mmdb";
      flake = false;
    };
  };
  outputs = {
    self,
    nixpkgs,
    flake-utils,
    geoip2-asn,
    geoip2-city,
    geoip2-country,
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = import nixpkgs {inherit system;};

      geoip-archive = pkgs.callPackage ./pkgs/geoip-archive.nix {
        inherit geoip2-asn geoip2-city geoip2-country;
      };

      e11sync-static = pkgs.callPackage ./pkgs/e11sync-static.nix {
        inherit self;
      };

      e11sync = pkgs.callPackage ./pkgs/e11sync.nix {
        inherit self geoip-archive;
      };
    in {
      packages.geoip-archive = geoip-archive;
      packages.e11sync-static = e11sync-static;
      packages.e11sync = e11sync;

      checks.e11sync-unit = e11sync.passthru.tests.unit;

      apps.e11sync-gunicorn = {
        type = "app";
        name = "e11sync-gunicorn";
        program = toString (pkgs.writeShellScript "wrapper" ''
          export E11SYNC_DATABASE_PATH=$PWD/db.sqlite3
          exec ${e11sync}/bin/e11sync-gunicorn
        '');
      };

      devShells.default = pkgs.mkShellNoCC {
        packages = with pkgs; [
          python3Packages.django-debug-toolbar
          python3Packages.django_5
          python3Packages.django-compressor
          python3Packages.geoip2
          libmaxminddb
          dart-sass
        ];
        GEOIP_PATH = "${geoip-archive}";
        E11SYNC_DEBUG = "1";
        LOCALE_ARCHIVE = "${pkgs.glibcLocales}/lib/locale/locale-archive";
      };

      formatter = pkgs.alejandra;
    });
}