const std = @import("std");
const pad = @import("padding.zig");

const assert = std.debug.assert;
const Allocator = std.mem.Allocator;
const ArrayList = std.ArrayList;
const cast = std.math.cast;

pub const PackedUserSize = @divExact(@bitSizeOf(PackedUser), 8);
pub const PackedUser = packed struct {
    uid: u32,
    gid: u32,
    additional_gids_offset: u29,
    shell_here: bool,
    shell_len_or_idx: u6,
    home_len: u6,
    name_is_a_suffix: bool,
    name_len: u5,
    gecos_len: u8,
};
const PackedUserAlignmentBits = 3;

pub const User = struct {
    uid: u32,
    gid: u32,
    name: []const u8,
    gecos: []const u8,
    home: []const u8,
    shell: []const u8,
};

// UserWriter accepts a naive User struct and returns a PackedUser
pub const UserWriter = struct {
    // shellIndexFnType is a signature for a function that accepts a shell
    // string and returns it's index in the global shell section. Passing a
    // function makes tests easier, and removes the Shell dependency of this
    // module.
    const shellIndexFnType = fn ([]const u8) ?u6;

    appendTo: *ArrayList(u8),
    shellIndexFn: shellIndexFnType,

    pub fn init(appendTo: *ArrayList(u8), shellIndexFn: shellIndexFnType) UserWriter {
        return UserWriter{
            .appendTo = appendTo,
            .shellIndexFn = shellIndexFn,
        };
    }

    pub fn downCast(comptime T: type, n: u64) error{InvalidRecord}!T {
        return std.math.cast(T, n) catch |err| switch (err) {
            error.Overflow => {
                return error.InvalidRecord;
            },
        };
    }

    pub fn appendUser(self: *UserWriter, user: User) !void {
        const home_len = try downCast(u6, user.home.len - 1);
        const name_len = try downCast(u5, user.name.len - 1);
        const shell_len = try downCast(u6, user.shell.len - 1);
        const gecos_len = try downCast(u8, user.gecos.len);

        var puser = PackedUser{
            .uid = user.uid,
            .gid = user.gid,
            .additional_gids_offset = std.math.maxInt(u29), // needs second pass
            .shell_here = self.shellIndexFn(user.shell) == null,
            .shell_len_or_idx = self.shellIndexFn(user.shell) orelse shell_len,
            .home_len = home_len,
            .name_is_a_suffix = std.mem.endsWith(u8, user.home, user.name),
            .name_len = name_len,
            .gecos_len = gecos_len,
        };

        try self.appendTo.appendSlice(std.mem.asBytes(&puser));
        try self.appendTo.appendSlice(user.home);
        if (!puser.name_is_a_suffix) {
            try self.appendTo.appendSlice(user.name);
        }
        try self.appendTo.appendSlice(user.gecos);
        if (puser.shell_here) {
            try self.appendTo.appendSlice(user.shell);
        }

        try self.appendTo.appendNTimes(0, pad.roundUpPadding(
            u64,
            PackedUserAlignmentBits,
            self.appendTo.items.len,
        ));
    }
};

pub const UserReader = struct {
    const shellIndexProto = fn (u10) []const u8;

    shellIndex: shellIndexProto,
    blob: []const u8,

    pub const PackedUserEntry = struct {
        packed_user: *PackedUser,
        blob: []const u8,
    };

    pub fn init(shellIndex: shellIndexProto, blob: []const u8) UserReader {
        return UserReader{
            .shellIndex = shellIndex,
            .blob = blob,
        };
    }

    pub const PackedUserIterator = struct {
        ur: *const UserReader,
        index: u32 = 0,

        pub fn next(it: *PackedUserIterator) ?PackedUserEntry {
            if (it.index == it.ur.blob.len) return null;
            assert(it.index < it.blob.len);

            const start = it.index;
            const end = it.index + it.index + @sizeOf(PackedUser);
            var pu = std.mem.bytesAsValue(it.ur.blob[start..end]);
            _ = pu;
        }
    };
};

const testing = std.testing;

test "PackedUser is byte-aligned" {
    try testing.expectEqual(0, @rem(@bitSizeOf(PackedUser), 8));
}

fn testShellIndex(shell: []const u8) ?u6 {
    if (std.mem.eql(u8, shell, "/bin/bash")) {
        return 0;
    } else if (std.mem.eql(u8, shell, "/bin/zsh")) {
        return 1;
    }
    return null;
}

test "construct PackedUser blob" {
    var buf = ArrayList(u8).init(testing.allocator);
    defer buf.deinit();

    var writer = UserWriter.init(&buf, testShellIndex);
    const user1 = User{
        .uid = 1000,
        .gid = 1000,
        .name = "vidmantas",
        .gecos = "Vidmantas Kaminskas",
        .home = "/home/vidmantas",
        .shell = "/bin/bash",
    };
    const user2 = User{
        .uid = 1001,
        .gid = 1001,
        .name = "svc-foo",
        .gecos = "Service Account",
        .home = "/home/service1",
        .shell = "/usr/bin/nologin",
    };
    try writer.appendUser(user1);
    try writer.appendUser(user2);
}