zig/build.zig

const std = @import("std");
const builtin = @import("builtin");

const headers = &[_][]const u8{
    "common.h",
    "ast.h",
    "parser.h",
};

const c_lib_files = &[_][]const u8{
    "tokenizer.c",
    "ast.c",
    "zig0.c",
    "parser.c",
};

const all_c_files = c_lib_files ++ &[_][]const u8{"main.c"};

const cflags = &[_][]const u8{
    "-std=c11",
    "-Wall",
    "-Wvla",
    "-Wextra",
    "-Werror",
    "-Wshadow",
    "-Wswitch",
    "-Walloca",
    "-Wformat=2",
    "-fno-common",
    "-Wconversion",
    "-Wuninitialized",
    "-Wdouble-promotion",
    "-fstack-protector-all",
    "-Wimplicit-fallthrough",
    "-Wno-unused-function", // TODO remove once refactoring is done
    //"-D_FORTIFY_SOURCE=2", // consider when optimization flags are enabled
};

pub fn build(b: *std.Build) !void {
    const target = b.standardTargetOptions(.{});
    const optimize = b.standardOptimizeOption(.{});

    const cc = b.option([]const u8, "cc", "C compiler") orelse "zig";

    const test_step = b.step("test", "Run unit tests");
    const test_mod = b.createModule(.{
        .root_source_file = b.path("test_all.zig"),
        .optimize = optimize,
        .target = target,
    });
    test_mod.addIncludePath(b.path("."));

    // TODO(zig 0.16+): remove this if block entirely; keep only the addLibrary branch.
    // Also delete addCObjectsDirectly.
    // Zig 0.15's ELF archive parser fails on archives containing odd-sized objects
    // (off-by-one after 2-byte alignment). This is fixed on zig master/0.16.
    if (comptime builtin.zig_version.order(.{ .major = 0, .minor = 16, .patch = 0 }) == .lt) {
        addCObjectsDirectly(b, test_mod, cc, optimize);
    } else {
        const lib_mod = b.createModule(.{
            .optimize = optimize,
            .target = target,
            .link_libc = true,
        });
        const lib = b.addLibrary(.{
            .name = "tokenizer",
            .root_module = lib_mod,
        });
        addCSources(b, lib.root_module, cc, optimize);
        test_mod.linkLibrary(lib);
    }

    const no_exec = b.option(bool, "no-exec", "Compile test binary without running it") orelse false;
    const test_exe = b.addTest(.{ .root_module = test_mod });
    if (no_exec) {
        const install = b.addInstallArtifact(test_exe, .{});
        test_step.dependOn(&install.step);
    } else {
        test_step.dependOn(&b.addRunArtifact(test_exe).step);
    }

    const fmt_step = b.step("fmt", "clang-format");
    const clang_format = b.addSystemCommand(&.{ "clang-format", "-Werror", "-i" });
    for (all_c_files ++ headers) |f| clang_format.addFileArg(b.path(f));
    fmt_step.dependOn(&clang_format.step);

    const lint_step = b.step("lint", "Run linters");

    const clang_analyze = b.addSystemCommand(&.{
        "clang",
        "--analyze",
        "--analyzer-output",
        "text",
        "-Wno-unused-command-line-argument",
        "-Werror",
    });
    for (all_c_files) |cfile| clang_analyze.addFileArg(b.path(cfile));
    lint_step.dependOn(&clang_analyze.step);

    const gcc_analyze = b.addSystemCommand(&.{
        "gcc",
        "--analyzer",
        "-Werror",
        "-o",
        "/dev/null",
    });
    for (all_c_files) |cfile| gcc_analyze.addFileArg(b.path(cfile));
    lint_step.dependOn(&gcc_analyze.step);

    const cppcheck = b.addSystemCommand(&.{
        "cppcheck",
        "--quiet",
        "--error-exitcode=1",
        "--check-level=exhaustive",
        "--enable=all",
        "--suppress=missingIncludeSystem",
        "--suppress=checkersReport",
        "--suppress=unusedFunction", // TODO remove after plumbing is done
        "--suppress=unusedStructMember", // TODO remove after plumbing is done
        "--suppress=knownConditionTrueFalse", // TODO remove after plumbing is done
    });
    for (all_c_files) |cfile| cppcheck.addFileArg(b.path(cfile));
    lint_step.dependOn(&cppcheck.step);
}

fn addCSources(
    b: *std.Build,
    mod: *std.Build.Module,
    cc: []const u8,
    optimize: std.builtin.OptimizeMode,
) void {
    if (std.mem.eql(u8, cc, "zig")) {
        mod.addCSourceFiles(.{ .files = c_lib_files, .flags = cflags });
    } else for (c_lib_files) |cfile| {
        const cc1 = b.addSystemCommand(&.{cc});
        cc1.addArgs(cflags ++ .{"-g"});
        cc1.addArg(switch (optimize) {
            .Debug => "-O0",
            .ReleaseFast, .ReleaseSafe => "-O3",
            .ReleaseSmall => "-Os",
        });
        cc1.addArg("-c");
        cc1.addFileArg(b.path(cfile));
        cc1.addArg("-o");
        mod.addObjectFile(cc1.addOutputFileArg(b.fmt("{s}.o", .{cfile[0 .. cfile.len - 2]})));
    }
}

// TODO(zig 0.16+): delete this function.
fn addCObjectsDirectly(
    b: *std.Build,
    mod: *std.Build.Module,
    cc: []const u8,
    optimize: std.builtin.OptimizeMode,
) void {
    addCSources(b, mod, cc, optimize);
    mod.linkSystemLibrary("c", .{});
}